Quelle  PANEL.rexx

/* REXX gr */                                                                   
/* ---------------------------------------------------------------- */          
/*                                                                  */          
/* Display Member List of first parameter                           */          
/* and accept commands                                              */          
/*                                                                  */          
/* ---------------------------------------------------------------- */          
   'ISREDIT MACRO (MI) NOPROCESS'                                               
   address "ISPEXEC" "CONTROL ERRORS RETURN"                                    
   if MI     = "" then                                                          
      arg MI                                                                    
   parse var MI datasetName                                                     
   if MI = "MI" ! MI="?" then do                                                
      call help                                                                 
      exit(0)                                                                   
   end                                                                          
   if datasetName  = ''                                                         
      then do                                                                   
              say 'parameter missing at entry to REXX Panel'                    
              return 1                                                          
      end                                                                       
   y = "'"datasetName"' directory recall"                                       
   x = msg('off')                                                               
   x = listdsi(y)                                                               
   if x > 4 then do                                                             
                    say 'function LISTDSI for dataset' datasetName,             
                        'not successful, SYSREASON = ' sysreason                
                    return 1                                                    
                 end                                                            
   if sysdsorg <> 'PO' then do                                                  
                               say 'dataset' datasetName 'not PO'               
                               return 1                                         
                            end                                                 
   if sysmembers = 0 then do                                                    
                             say 'dataset' datasetName 'without members'        
                             return 1                                           
                          end                                                   
   x = msg('on')                                                                
   y = "'"datasetName"'"                                                        
   "ispexec lminit dataid(dsnID) dataset("y") "                                 
      if rc > 8 then call errorExit                                             
      if rc = 8 then do                                                         
                        say zerrmsg zerrlm                                      
                        call errorExit                                          
                     end                                                        
   "ispexec lmopen dataid("dsnID") "                                            
      if rc <> 0 then call errorExit                                            
   lmmrc = 0                                                                    
   do while lmmrc = 0                                                           
   "ispexec lmmdisp dataid("dsnID") option(display) commands(ANY)"              
      lmmrc = rc                                                                
      if rc = 4 then do                                                         
                        say 'no matches for member pattern',                    
                            memberPrefix                                        
                        return 1                                                
                     end                                                        
   /*------------ Komando auswerten --------------*/                            
      if rc = 0 then do                                                         
        if index(zlmember,' ') > 0 then                                         
           zlmember = substr(zlmember,1,index(zlmember,' ')-1)                  
         if (zllcmd = 'e') ! (zllcmd = 'E') then                                
        address "ISPEXEC" edit "DATASET('"datasetName"("zlmember")')"           
         else if (zllcmd = 'b') ! (zllcmd = 'B'),                               
                 ! (zllcmd = 's') ! (zllcmd = 'S') then                         
        address "ISPEXEC" browse "DATASET('"datasetName"("zlmember")')"         
         else if (zllcmd = 'v') ! (zllcmd = 'V') then                           
        address "ISPEXEC" view "DATASET('"datasetName"("zlmember")')"           
         else if (zllcmd = 'd') ! (zllcmd = 'D') then                           
        address tso "del ('"datasetName"("zlmember")')"                         
        else                                                                    
          say "unknown command"                                                 
      end                                                                       
   end                                                                          
   "ispexec lmclose dataid("dsnID") "                                           
      if rc <> 0 then call errorExit                                            
   return 0                                                                     
                                                                                
/*==================================================================*/          
/*   Subroutine:  errorExit                                         */          
/*   Description: put error-message to screen                       */          
/*                terminates the exec                               */          
/*   Usage:       call errorExit                                    */          
/*==================================================================*/          
errorExit:                                                                      
   msgNumber = sigl                                                             
   say 'Dataset in error RC='rc' sigl='sigl                                     
   exit   1                                                                     
                                                                                
help:                                                                           
say '                                                                '          
say 'ISPF/PDF edit macro to show a member selection list for the     '          
say 'dataset specified in parm1                                      '          
say '                                                                '          
say 'parm 1:                                                         '          
say '   the dataset                                                  '          
say '                                                                '          
say '   If you have questions about this command,                    '          
say '   contact Hamburg -4244.                                       '          
return